Skip to content Skip to sidebar Skip to footer

Membuat Laporan Stok Barang Dengan Excel Untuk Dua Gudang Berbeda


Laporan Stok Barang Dengan Excel - Dalam artikel sebelumnya kita telah membahas tentang cara membuat laporan stok barang.


Kemudian apa perbedaan artikel tersebut dengan artikel yang akan kita bahas kali ini ?

Dalam artikel sebelumnya lokasi gudang hanya terdiri dari satu tempat atau satu lokasi sedangkan dalam artikel ini lokasi dari gudang tersebut terdiri dari 2 tempat.

Yang dimkasud 2 tempat adalah gudang yang berada di dua lokasi misalnya di gedung yang berbeda atau dilantai yang berbeda.

Jika mutasi dan stoknya digabungkan padahal posisi barang ada di dua lokasi maka kita akan menemui kesulitan pada saat pemeriksaan fisik barang.

Pada dasarnya perbedaan lokasi ini bisa diatasi dengan menambahkan kode lokasi gudang pada sheet mutasi dan data barang.

Jika telah menguasai rumus yang digunakan maka kita hanya tinggal menambahkan kode gudang tersebut.




Dalam artikel ini saya akan menjelaskan tentang membuat laporan stok barang untuk dua gudang yang berbeda.

Cara Membuat Laporan Stok Barang Dalam Microsoft Excel


Untuk dapat membuat laporan stok ini tentu kita akan menggunakan beberapa bantuan rumus sehingga proses penghitungan dilakukan secara otomatis.

Pola yang saya gunakan tetap sama dengan contoh pada artikel sebelumnya, jadi silahkan pelajari untuk memudahkan pemahaman terhadap artikel ini.


Rumus Menghitung Stok Barang Dalam Excel



Hampir sama seperti pada artikel sebelumnya rumus yang digunakan dalam contoh penghitungan stok barang ini adalah SUMIFS dan VLOOKUP, hanya saja terdapat satu tambahan rumus yaitu IF.

SUMIF dan SUMIFS digunakan untuk menjumlahkan range tertentu dengan syarat atau kondisi yang telah ditentukan.

VLOOKUP digunakan untuk mengambil cell tertentu berdasarkan referensi dari sebuah cell.

Untuk ketiga rumus tersebut telah saya pelajari dalam artikel sebelumnya, silahkan untuk dipelajari.


Contoh Membuat Laporan Stok Barang Untuk Dua Gudang




Dalam contohnya saya buat mirip seperti pada contoh yang pertama, terdapat tiga sheet Excel yaitu Data Barang, Mutasi dan Kartu Stok.

Untuk fungsi dan rumus dari masing - masing sheet tersebut akan saya bahas satu persatu dibawah ini :


1. Sheet Data Barang


Sheet data barang ini diisi dengan informasi barang, stok awal, mutasi dan stok akhir.

Untuk memisahkan masing - masing gudang saya buatkan kode yaitu G-001 untuk gudang pertama dan G-002 untuk gudang kedua.

Penulisan kode gudang ini ada pada stok awal, mutasi dan stok akhir untuk memisahkan stok masing - masing gudang tersebut.

Untuk formatnya dibuat seperti tampak pada gambar dibawah ini :



rumus menghitung stko barang


Untuk Periode, No, Kode Barang, Nama Barang dan Stok Awal silahkan isi manual sesuai dengan periode dan kode dari masing - masing barang.

Untuk mutasi saya menggunakan rumus SUMIFS untuk menjumlahkan masing - masing mutasi barang dari sheet Mutasi.

Untuk rumus - rumusnya adalah sebagai berikut :


- Cell G11 (Kolom Mutasi In Gudang G-001)


Kolom ini akan menjumlahkan mutasi barang dari sheet Mutasi khusus untuk mutasi masuk yang berlokasi pada gudang pertama.

Pada cell G11 masukan rumus sebagai berikut :

=SUMIFS(Mutasi!$H$6:$H$24;Mutasi!$C$6:$C$24;'Data Barang'!B11;Mutasi!$D$6:$D$24;"G-001") 

Mutasi!$H$6:$H$24 : Kolom pembelian pada Sheet Mutasi
Mutasi!$C$6:$C$24 : Kolom Kode Barang pada Sheet Mutasi
'Data Barang'!B11 : Cell Kode Barang pada Sheet Data Barang
Mutasi!$D$6:$D$24 : Kolom Kode Gudang pada Sheet Mutasi
"G-001" : Kode gudang untuk Gudang Pertama

Untuk cell G12 sampai dengan G20 silahkan copy pastekan rumus tersebut diatas.


Cell H11 (Kolom Mutasi Out Gudang G-001) 


Kolom ini menghitung jumlah mutasi pengeluaran barang dari sheet Mutasi kolom Penjualan.

Untuk cell H11 masukan rumus sebagai berikut :


=SUMIFS(Mutasi!$I$6:$I$24;Mutasi!$C$6:$C$24;'Data Barang'!B11;Mutasi!$D$6:$D$24;"G-001")


Untuk cell selanjutnya silahkan copy pastekan rumus tersebut.


Cell I11 (Kolom Mutasi In Gudang G-002) 


Kolom ini akan menghitung jumlah pengeluara barang berdasarkan sheet mutasi kolom penjualan.

Untuk cell I11 masukan rumus sebagai berikut :


=SUMIFS(Mutasi!$H$6:$H$24;Mutasi!$C$6:$C$24;'Data Barang'!B11;Mutasi!$D$6:$D$24;"G-002")


Untuk cell I12 sampai dengan I20 copy pastekan rumus tersebut.


Cell J11 (Kolom Mutasi Out Gudang G-002)


Kolom ini akan menghitung jumlah mutasi pengeluaran barang untuk gudang kedua berdasarkan sheet Mutasi.

Untuk cell J11 masukan rumus sebagai berikut :


=SUMIFS(Mutasi!$I$6:$I$24;Mutasi!$C$6:$C$24;'Data Barang'!B11;Mutasi!$D$6:$D$24;"G-002")


Khusus untuk kolom Stok Akhir saya tidak akan membahas rumusnya karena hanya menggunakan penambahan dan pengurangan saja.


2. Sheet Mutasi


Sheet ini akan menampung seluruh transaksi penerimaan dan pengeluaran barang untuk dua gudang tersebut.

Tampilannya adalah sebagai berikut :



membuat laporan stok barang


Untuk memisahkan gudang pertama dan kedua digunakan kode gudang yaitu G-001 dan G-002.

Untuk kolom D atau Kode Gudang sudah saya buatkan dropdown list dengan isi G-001 dan G-002 sehingga memudahkan kita pada saat menentukan kode gudang.

Pada sheet ini yang menggunakan rumus hanya kolom F atau Nama Barang dan untuk kolom lainnya silahkan diisi secara manual.

Untuk cell F6 masukan rumus sebagai berikut :


=IFERROR(VLOOKUP(C6;'Data Barang'!$B$11:$C$20;2;0);"")


Untuk cell seterusnya silahkan copy pastekan rumus tersebut.


3. Sheet Kartu Stok


Sheet ini digunakan untuk mencetak Kartu Stok jika dibutuhkan. Untuk pilihannya bisa hanya Gudang pertama atau kedua atau juga seluruha mutasi barang.

Rumus yang saya gunakan dalam shee ini adalah sebagai berikut :


- Cell B5 (Gudang)


Cell ini diisi dengan drop down list dengan pilihan G-001 untuk gudang pertama, G-002 untuk gudang kedua dan All untuk gabungan dua gudang tersebut.

Untuk cara membuat dropdown listnya silahkan baca dalam artikel sebelumnya yang telah dibahas.


- Cell B6 (Nama Barang)


Cell ini akan memunculkan Nama Barang dari Sheet Data Barang sesuai dengan Kode Barang pada cell B5.

Masukan rumus sebagai berikut :


=IFERROR(VLOOKUP(B4;'Data Barang'!$B$11:$C$20;2;0);"")


Dengan rumus tersebut maka Nama Barang akan otomatis berubah sesuai dengan Kode yang kita pilih.


- Cell B7 (Stok Awal)


Cell ini akan menampilkan stok awal barang sesuai dengan kode barang dan juga pilihan gudang.

Untuk rumusnya masukan sebagai berikut :


=IF(B5="G-001";VLOOKUP(B4;'Data Barang'!$B$11:$F$20;3;0);IF(B5="G-002";VLOOKUP(B4;'Data Barang'!$B$11:$F$20;4;0);IF(B5="All";VLOOKUP(B4;'Data Barang'!$B$11:$F$20;5;0);0)))


Rumus ini akan memisahkan pilihan kode barang dan juga pilihan gudang pada cell B5.


- Kolom C (Stok Masuk)


Kolom ini akan menghitung mutasi barang masuk berdasarkan Kode Barang, Gudang dan tanggal transaksi pada periode tersebut.

Untuk cell C11 masukan rumus sebagai berikut :


=IF($B$5="G-001";SUMIFS(Mutasi!$H$6:$H$24;Mutasi!$C$6:$C$24;'Kartu Stok'!$B$4;Mutasi!$B$6:$B$24;'Kartu Stok'!B11;Mutasi!$D$6:$D$24;'Kartu Stok'!$B$5);IF($B$5="G-002";SUMIFS(Mutasi!$H$6:$H$24;Mutasi!$C$6:$C$24;'Kartu Stok'!$B$4;Mutasi!$B$6:$B$24;'Kartu Stok'!B11;Mutasi!$D$6:$D$24;'Kartu Stok'!$B$5);IF($B$5="All";SUMIFS(Mutasi!$H$6:$H$24;Mutasi!$C$6:$C$24;'Kartu Stok'!$B$4;Mutasi!$B$6:$B$24;'Kartu Stok'!B11);0)))


Rumus tersebut bisa digunakan untuk memisahkan masing - masing Kode Barang dan juga pilihan Gudang yaitu G-001, G-002 atau All.

Untuk cell selanjutnya silahkan copy pastekan rumus tersebut.


- Kolom D (Stok Keluar)


Kolom ini akan menghitung mutasi pengeluaran barang dari Kode Barang dan Gudang yang dipilih.

Untuk cell D11 masukan rumus sebagai berikut :


=IF($B$5="G-001";SUMIFS(Mutasi!$I$6:$I$24;Mutasi!$C$6:$C$24;'Kartu Stok'!$B$4;Mutasi!$B$6:$B$24;'Kartu Stok'!B11;Mutasi!$D$6:$D$24;'Kartu Stok'!$B$5);IF($B$5="G-002";SUMIFS(Mutasi!$I$6:$I$24;Mutasi!$C$6:$C$24;'Kartu Stok'!$B$4;Mutasi!$B$6:$B$24;'Kartu Stok'!B11;Mutasi!$D$6:$D$24;'Kartu Stok'!$B$5);IF($B$5="All";SUMIFS(Mutasi!$I$6:$I$24;Mutasi!$C$6:$C$24;'Kartu Stok'!$B$4;Mutasi!$B$6:$B$24;'Kartu Stok'!B11);0)))


Untuk cell selanjutnya silahkan copy pastekan rumus tersebut.

Untuk kolom Stok Akhir silahkan tambahkan dan kurangi karena rumusnya sangat mudah.

Untuk contoh filenya silahkan ambil pada link dibawah ini :


Nama File : Contoh Stok Dua Gudang
Format: .xlsx
Ukuran : 26 kb
Pwd :

File contoh tersebut hanya digunakan sebagai pelengkap untuk memahami rumus yang digunakan.

Download content is locked! Please share it & unlock the content

Informasikan kepada saya melalui kolom komentar, email atau FP Facebook jika link contoh file bermasalah.

Saya meperbolehkan untuk dimodifikasi sesuai dengan kebutuhan, tetapi mohon untuk tidak menguploadnya kembali atau menyebarkan file ini melalui web atau blog lain tanpa seizin dari saya.

Itulah penjelasan tentang cara membuat laporan stok barang dengan rumus Excel, semoga artikel ini bermanfaat untuk pembaca. 

Post a Comment for "Membuat Laporan Stok Barang Dengan Excel Untuk Dua Gudang Berbeda"