Menghitung Stok Barang Untuk Beberapa Gudang Yang Berbeda Dalam Excel

Cara Menghitung Stok Barang - Proses menghitung stok barang pada dasarnya bisa dilakukan dengan berbagai macam cara.

Salah satu cara yang bisa digunakan untuk menghitung atau mengolah data stok barang adalah Microsoft Excel.

Dalam artikel sebelumnya kita telah membahas cara menghitung stok barang dengan kondisi yang berbeda - beda.

Kondisi yang pertama adalah menghitung stok barang dari satu gudang saja sedangkan kondisi yang kedua jumlah gudang terdiri dari dua lokasi.

Dalam pembahasan yang ketiga ini kita sedikit berbeda dengan kondisi yang kedua yaitu jumlah gudang lebih dari dua sehingga kita bisa menyesuaikan antara posisi gudang dengan stok barang yang kita catat.

Memang adakalanya untuk kebutuhan tertentu gudang ini dipisahkan misalnya gudang bahan kimia dengan gudang bahan makanan atau gudang elektronik dengan gudang furniture.

Cara Menghitung Stok Barang

Secara umum cara menghitung stok barang dalam Excel menggunakan kode sebagai alat untuk menghubungkan rumus Excel yang satu dengan yang lainnya.

Perbedaan yang paling mendasar antara penghitungan stok barang untuk dua gudang dengan penghitungan stok barang dengan beberapa gudang adalah pemberian kode barang sebagai idntitas utama dari gudang yang akan kita hitung stoknya.

Dalam prosesnya kita akan membuuthkan beberapa data sebagai alat entry kedalam penghitungan, yaitu :

1. Stok Awal Barang

Stok awal barang merupakan saldo atau sisa barang yang ada digudang pada awal periode atau awal bulan.

Jika penghitungan stok barang ini dilakukan pada awal periode atau awal berdirinya perusahaan maka stok awal barang ini tidak akan ada.

2. Penerimaan Barang

Biasanya dalam pengelolaan stok barang istilah penerimaan ini lebih dikenaal dengan barang masuk atau In.

Sumber penerimaan barang ini biasanya dari pembelian barang, mutasi antar gudang atau retur penjualan.

3. Pengeluaran Barang

Sumber data utama untuk pengisian pengeluaran barang ini adalah penjualan atau mutasi barang atau bisa juga dari data pemusnahan stok yang sudah tidak terpakai.

Rumus dasar untuk menghitung stok barang berdasarkan sumber data - data diatas adalah stok awal ditambah dengan pembelian barang dan dikurangi dengan pengeluaran barang.

Rumus Excel Untuk Menghitung Stok Barang Dengan Beberapa Gudang

Untuk bisa menghitung saldo akhir atau stok akhir barang ini tentu saja kita akan menggunakan bantuan beberapa rumus Excel.

Secara umum pola yang akan kita gunakan untuk menghitung stok barang dengan lokasi gudang yang berbeda adalah sebagai berikut :

Membuat tabel Data Gudang, Data Customer dan Data Vendor
Membuat Tabel Data Barang
Membuat Tabel Stok Awal Barang
Membuat Tabel Penerimaan Barang
Membuat Tabel Pengeluaran Barang
Membuat Tabel Stok Akhir
Membuat Tabel Sampling Stok

Masing - masing point diatas akan dibuat dalam sheet tersendiri dan saling berkaitan antara sheet yang satu dengan yang lainnya.

Dari ketujuh sheet diatas yang palign utama adalah tabel stok akhir karena tabel tersebut akan menampilkan stok akhir dari masing - masing gudang dan masing - masing nama barang.

Sedangkan rumus yang akan digunakan untu menghitung barang ini adalah sebagai berikut :

Rumus VLOOKUP : rumus Excel ini digunakan untuk mengambil nama barang berdasarkan kode barang serta mengambil nama gudang sesuai dengan kode yang diberikan.
Rumus IFERROR : rumus IFERROR digunakan untuk memberikan angka atau parameter tertentu pada saat kondisi rumus atau pengambilan data bernilai error.
Rumus IF : rumus ini digunakan untuk menguji kondisi pada saat muncul parameter tertentuk untuk menampilkan data.
Rumus AND : rumus ini akan digabungkan dengan rumus IF untuk menambahkan kondisi atau kriteria pada argumen logical_test.
Rumus SUMIF : digunakan untuk menjumlahkan range penerimaan atau pengeluaran dengan kriteria yang telah dipisahkan oleh rumus IF dan AND.
SUMIFS : hampir sama fungsinya dengan SUMIF hanya saja kriteria yang diberikan lebih dari satu.

Untuk memudahkan pemahaman terhadap pola yang digunakan silahkan pelajari rumus - rumus Excel tersebut diatas.

Rumus Excel VLOOKUP tergabung kedalam kelompok Fungsi Pencarian dan Referensi sedangkan rumus Excel SUMIF dan SUMIFS tergabung kedalam kelompok Fungsi Matematika.

Khusus untuk rumus Excel IF, IFERROR dan AND merupakan rumus utama yang ada dalam pengolahan stok barang ini sehingga harus benar - benar dipahami dan silahkan pelajari dalam kelompok Fungsi Logika.

Contoh Menghitung Stok Barang Untuk Beberapa Gudang Dalam Excel

Setelah memahami cara penggunaan rumus - rumus Excel diatas selanjutnya kita akan membuat tabel serta memasukan rumus satu persatu kedalam tabel - tabel tersebut.

Untuk lebih rincinya silahkan ikuti setiap langkah yang akan saya jelaskan dibagian bawah berikut ini.

1. Membuat Tabel Data

Buatlah beberapa tabel dalam sheet satu sebagai tabel master data yang akan digunakan untuk mengisi penghitungan stok.

Tabel - tabel tersebut adalah Gudang, Data Vendor, Data Customer dengan kolom yang terdiri dari : No, Kode, Nama, Alamat, PIC/Telp dan keterangan.

Untuk contoh tampilannya silahkan perhatikan gambar berikut ini :

Dari contoh gambar diatas terlihat bahwa dalam sheet ini kita tidak memasukan rumus Excel apapun karena isi dari tabel - tabel tersebut adalah data awal saja.

Perhatikan, untuk kolom Kode sifatnya wajib untuk diisi karena ini akan menjadi kode yang digunakan dalam penghitungan.

Selain itu perhatikan juga untuk sheet1 sudah diganti namanya menjadi sheet Data tetapi ini bisa disesuaikan atau boleh diganti dengan nama yang lain.

Selanjutnya, setelah tabel - tabel tersebut dibuat maka silahkan isi data dengan lengkap sehingga semua informasi yang dibutuhkan telah tersedia dalam sheet tersebut.

2. Membuat Tabel Nama Barang

Tabel yang kedua dan tentu saja dalam sheet yang kedua kita akan membuat tabel nama barang yang dilengkapi dengan seluruh keterangan yang berkaitan dengan barang misalnya kode, satuan dan lainnya.

Untuk kolom - kolom yang dibuat dalam tabel data barang ini adalah No, Kode Barang, Nama Barang, Satuan dan Detail Barang.

Silahkan buat tabelnya sesuai dengan urutan nama kolom - kolom diatas dan selanjutnya silahakn masukan data barang kedalam tabel tersebut.

Perlu diperhatikan, yang terpenting dari pengisian tabel ini adalah kode barang dan ini wajib untuk diisi.

Hampir sama dengan tabel yang pertama, tabel yang kedua ini tidak ada rumus yang digunakan serta sheet2 telah saya ubah namanya menjadi Barang.

3. Membuat Tabel Stok Awal

Tabel yang ketiga adalah tabel Stok Awal barang, tabel ini akan memuat stok awal barang dari seluruh gudang dengan memasukan kode gudang yang telah kita buat dalam sheet yang pertama.

Adapun kolom - kolom yang dibuat dalam tabel ini adalah No, Kode Gudang, Kode Barang, Nama Barang, Jumlah dan satuan.

Untuk contoh tampilan tabel dalam sheet yang ketiga adalah sebagai berikut :

Dalam gambar diatas terlihat ada kolom yang diberikan warna abu, kolom tersebut sudah diberikan rumus Excel sehingga kita tidak perlu untuk mengisi secara manual.

Untuk kolom Kode Gudang dan Kode Barang kita akan buat dengan menu dropdown list sehingga tidak ada kesalahan ketik pada kedua kode tersebut yang bisa mengakibatkan error pada penghitungan stok akhir.

Pembuatan dropdown list dalam Excel telah saya bahas dalam artikel yang lain silahkan untuk dipelajari.

Cara pengisian dari tabel ini adalah klik pada kolom Kode Gudang dan pilih kode gudang yang bersangkutan.

Setelah memilih kode gudang maka selanjutnya klik dan pilih Kode Barang sehingga nama barang dan satuan akan otomatis terisi sesuai dengan kode barang yang dipilih dari tabel barang yang ada dalam sheet Barang.

Rumus Excel yang digunakan untuk mengisi kolom Nama Barang dan Satuan adalah VLOOKUP yang digabungkan dengan IFERROR.

Seperti yang dijelaskan diatas bahwa rumus Excel VLOOKUP digunakan untuk mengambil data barang sesuai dengan kode yang diberikan.

Sedangkan penggabungan VLOOKUP dengan IFERROR bertujuan untuk menghilangkan error pada saat kolom Kode Barang belum diisi.

Silahkan perhatikan baris ke-16, kode barang dalam baris tersebut belum diisi tetapi kolom Nama Barang dan Satuan tidak menampilkan error apapun dan inilah fungsi dari IFERROR.

Rumus Excel IF dan VLOOKUP yang digunakan untuk kolom Nama Barang adalah sebagai berikut :

=IFERROR(VLOOKUP(C6;Barang!$B$6:$D$16;2;0);"")

Dengan rumus Exce tersebut maka ketika kita mengisi atau memilih Kode Barang dalam kolom C maka secara otomatis kolom Nama Barang akan terisi.

Sedangkan rumus Excel yang digunakan untuk mengisi kolom satuan adalah sebagai berikut :

=IFERROR(VLOOKUP(C6;Barang!$B$6:$D$16;3;0);"")

Pola dari rumus dalam kolom satuan ini sama dengan kolom Nama Barang yang membedakan adalah pemilihan kolom pada tabel Data Barang.

4. Membuat Tabel Penerimaan Barang

Tabel penerimaan barang akan kita isi dengan barang yang masuk ke gudang baik itu melalui pembelian barang ataupun mutasi barang antar gudang.

Kolom - kolom yang kita buat dalam tabel ini adalah No, No. Bukti, Tanggal, Kode Gudang, Nama Gudang, Kode Vendor, Nama Vendor, Kode Barang, Nama Barang, Qty dan Satuan.

Contoh tampilan yang telah saya buat dalam sheet yang ke-4 ini adalah sebagai berikut :

Silahkan perhatikan gambar diatas, untuk kolom - kolom yang saya beri warna sudah menggunakan rumus.

Untuk pengisian tabel ini adalah sebagai berikut :

- Isi kolom No. Bukti sesuai dengan bukti transaksi
- Isi kolom tanggal sesuai dengan tanggal yang tercantum dalam transaksi
- Isi kolom Kode Gudang
- Isi Kolom Kode Vendor
- Isi Kolom Kode Barang
- Isi kolom QTY sesuai dengan jumlah barang yang dikeluarkan

Pengisian kode gudang, kode vendor dan kode barang saya sarankan menggunakan dropdown list untuk menghindari kesalahan input.

Rumus - rumus yang digunakan dalam tabel diatas sama dengan tabel stok awal yaitu gabungan VLOOKUP dan IFERROR.

Adapun rumus - rumus tersebut adalah sebagai beriut :

Nama Gudang : =IFERROR(VLOOKUP(D6;Data!$C$7:$G$12;2;0);"")
Nama Vendor : =IFERROR(VLOOKUP(F6;Data!$C$18:$F$21;2;0);"")
Nama Barang : =IFERROR(VLOOKUP(H6;Barang!$B$6:$D$16;2;0);"")
Satuan : =IFERROR(VLOOKUP(H6;Barang!$B$6:$D$16;3;0);"")

Masukan rumus - rumus tersebut diatas dan jika muncul nama sheet dalam rumus tersebut itu artinya data yang diambil berasal dari sheet yang namanya tercantum dalam rumus tersebut.

Satu hal lagi yang tidak kalah pentingnya adalah sheet yang keempat ini sudah saya ganti dengan nama In.

5. Membuat Tabel Pengeluaran Barang

Tabel selanjutnya yang akan kita buat adalah Tabel Pengeluaran Barang dan tentu saja isi dari tabel ini adalah barang - barang yang dikeluarkan dari gudang.

Untuk nama - nama kolomnya adalah sebagai berikut : No, No. Bukti, Tanggal, Kode Gudang, Nama Gudang, Kode Vendor, Nama Vendor, Kode Barang, Nama Barang, QTY dan Satuan.

Untuk contoh tampilan dari tabel pengeluaran yang telah saya buat adalah sebagai berikut :

Hampir sama dengan tabel - tabel sebelumnya bahwa untuk kolom yang diberikan warna sudah ada rumusnya sehingga tidak diperlukan input secara manual.

Jika diperhatikan tampilan tabel pengeluaran barang ini sama dengan tampilan tabel penerimaan barang.

Pengisian tabel pengeluarn barang ini sama dengan cara pengisian tabel penerimaan barang hanya saja sumber transaksinya berbeda yaitu untuk pengeluaran barang berasal dari penjualan atau mutasi barang ke gudang lain.

Adapun rumus - rumus yang digunakan dalam tabel ini adalah sebagai berikut :

Nama Gudang : =IFERROR(VLOOKUP(D6;Data!$C$7:$G$12;2;0);"")
Nama Vendor : =IFERROR(VLOOKUP(F6;Data!$C$18:$F$21;2;0);"")
Nama Barang : =IFERROR(VLOOKUP(H6;Barang!$B$6:$D$16;2;0);"")
Satuan : =IFERROR(VLOOKUP(H6;Barang!$B$6:$D$16;3;0);"")

Data dalam tabel pengeluaran barang ini semua kolom wajib untuk diisi karena akan dimasukan kedalam penghitungan stok akhir dalam tabel selanjutnya.

6. Membuat Tabel Stok Barang

Tabel yang keenam ini merupakan tabel yang paling penting dari pembahasan kita kali ini.

Dalam tabel stok barang ini akan muncul jumlah stok akhir dari masing - masing barang dan juga masing - masing gudang sesuai dengan sumber data yang kita telah buat diatas.

Kolom - kolom yang dimasukan kedalam tabel Stok Barang adalah No, Kode Barang, Nama Barang, Stok Awal, In, Out, Jumlah dan Satuan.

Contoh tampilan yang telah saya buat untuk tabel Stok barang adalah sebagai berikut :

rumus excel untuk menghitung stok barang

Silahkan perhatikan gambar diatas, terdapat filter data sebagai dasar tampilan angka sesuai dengan pilihan yang kita inginkan.

Dengan flter data tersebut kita bisa menyesuaikan tampilan stok sesuai dengan yang kita butuhkan.

Ada beberapa kondisi yang bisa dipilih dalam filter data ini yaitu Tampilan Gudang, Pilih Gudang, Tampilan data, periode awal dan periode akhir.

- Jenis Tampilan Gudang

Tampilan ini akan memisahkan penghitungan barang berdasarkan pilihan gudang atau semua data.

Jika ingin menampilkan semua data maka silahkan pilih "Semua" dalam dropdown list yang telah dibuat tersebut.

Sedangkan untuk menampilkan data berdasarkan pilihan gudang tertntu silahkan pilih "Pilih Gudang".

- Pilih Gudang

Pada filter ini dropdown list berisi kode gudang yang telah kita buat dalam tabel gudang.

Fungsi dari filter ini adalah menampilkan stok dari gudang yang kodenya kita masukan kedalam pilihan ini.

Misalnya kita hanya ingin menampilkan stok dari gudang A saja maka lakukan filter pada bagian ini.

Pilihan pada dropdown ini sangat bergantung kepada pilihan pada dropdown list pertama karena jika dalam dropdown list pertama kita pilih "Semua" maka pilhan gudang pada dropdown ini tidak akan berfungsi.

- Jenis Tampilan Data

Pilihan ini merupakan filter untuk periode yang akan ditampilkan berdasarkan tanggal.

Jika ingin menampilkan data dari semua periode maka dalam dropdown list silahkan pilih "Semua".

Sedangkan jika ingin menampilkan stok akhir hanya pada periode tertetu saja silahkan pilih "Periode".

- Periode Awal dan Akhir

Setelah kita memilih "Periode" dalam dropdown list Jenis tampilan data maka selanjutnya kita harus mengisi tanggal awal serta tanggal akhir pada bagian ini.

Jika dalam jenis tapilan data yang dipilih adalah "Semua" maka tanggal awal dan akhir yang dimasukan tidak akan berfungsi.

Jadi, dari penjelasan diatas dapat disimpulkan bahwa terdapat dua jenis filter pada data tersebut yaitu berdasarkan gudang dan berdasarkan periode.

Untuk rumus yang digunakan memang cukup panjang karena untuk mengakomodir filter yang kita lakukan.

Rumus untuk kolom Nama Barang adalah sebagai berikut :

=IFERROR(VLOOKUP(C13;Barang!$B$6:$D$16;2;0);"")

Rumus tersebut memang hanya digunakan untuk mengambil data dari tabel Barang dan ini sama dengan rumus yang kita gunakan pada tabel penerimaan dan pengeluaran barang.

Rumus untuk kolom Stok Awal adalah sebagai berikut :

=IF(AND($D$5="Semua";$D$7="Semua");SUMIF('Stok Awal'!$C$6:$C$16;'Stok Barang'!C13;'Stok Awal'!$E$6:$E$16);IF(AND($D$5="Semua";$D$7="Periode");(SUMIF('Stok Awal'!$C$6:$C$16;'Stok Barang'!C13;'Stok Awal'!$E$6:$E$16)+SUMIFS(In!$J$6:$J$17;In!$H$6:$H$17;'Stok Barang'!C13;In!$C$6:$C$17;"<"&'Stok Barang'!$D$8)-(SUMIFS(Out!$J$6:$J$17;Out!$H$6:$H$17;'Stok Barang'!C13;Out!$C$6:$C$17;"<"&'Stok Barang'!$D$8)));IF(AND($D$5="Pilih Gudang";$D$7="Semua");SUMIFS('Stok Awal'!$E$6:$E$16;'Stok Awal'!$C$6:$C$16;'Stok Barang'!C13;'Stok Awal'!$B$6:$B$16;'Stok Barang'!$D$6);IF(AND($D$5="Pilih Gudang";$D$7="Periode");(SUMIFS('Stok Awal'!$E$6:$E$16;'Stok Awal'!$C$6:$C$16;'Stok Barang'!C13;'Stok Awal'!$B$6:$B$16;'Stok Barang'!$D$6)+SUMIFS(In!$J$6:$J$17;In!$H$6:$H$17;'Stok Barang'!C13;In!$D$6:$D$17;'Stok Barang'!$D$6;In!C6:C17;"<"&'Stok Barang'!$D$8)-SUMIFS(Out!$J$6:$J$17;Out!$H$6:$H$17;'Stok Barang'!C13;Out!$D$6:$D$17;'Stok Barang'!$D$6;Out!C6:C17;"<"&'Stok Barang'!$D$8));""))))

Rumus untuk stok awal ini sumber datanya berasal dari tabel Stok awal dan telah ditambahkan dengan kondisi filter untuk memisahkan periode dan pilihan gudang.

Update : Rumus untuk stok awal diatas sudah diubah karena pada rumus sebelumnya terdapat satu kriteria yang terlewatkan.

Rumus untuk kolom Mutasi In atau kolom F adalah sebagai berikut :

=IF(AND($D$5="Semua";$D$7="Semua");SUMIF(In!$H$6:$H$17;'Stok Barang'!C13;In!$J$6:$J$17);IF(AND($D$5="Pilih Gudang";$D$7="Semua");SUMIFS(In!$J$6:$J$17;In!$H$6:$H$17;'Stok Barang'!C13;In!$D$6:$D$17;'Stok Barang'!$D$6);IF(AND($D$5="Semua";$D$7="Periode");SUMIF(In!$H$6:$H$17;'Stok Barang'!C13;In!$J$6:$J$17)-SUMIFS(In!$J$6:$J$17;In!$H$6:$H$17;'Stok Barang'!C13;In!$C$6:$C$17;"<"&'Stok Barang'!$D$8)-SUMIFS(In!$J$6:$J$17;In!$H$6:$H$17;'Stok Barang'!C13;In!$C$6:$C$17;">"&'Stok Barang'!$D$9);IF(AND($D$5="Pilih Gudang";$D$7="Periode");SUMIFS(In!$J$6:$J$17;In!$H$6:$H$17;'Stok Barang'!C13;In!$D$6:$D$17;'Stok Barang'!$D$6)-SUMIFS(In!$J$6:$J$17;In!$H$6:$H$17;'Stok Barang'!C13;In!$C$6:$C$17;"<"&'Stok Barang'!$D$8;In!$D$6:$D$17;'Stok Barang'!$D$6)-SUMIFS(In!$J$6:$J$17;In!$H$6:$H$17;'Stok Barang'!C13;In!$C$6:$C$17;">"&'Stok Barang'!$D$9;In!$D$6:$D$17;'Stok Barang'!$D$6);""))))

Rumus tersebut diatas sumber datanya berasal dari tabel Penerimaan barang dengan kondisi sudah disesuaikan berdasarkan semua filter kondisi yang terdapat dalam kolom Filter.

Jika ingin mempelajarinya silahkan pisahkan terlebih dahulu rumus tersebut sesuai dengan kondisinya karena pada dasarnya rumus tersebut hanya menggabungkan rumus Excel IF dengan tambahan AND untuk memisahkan kondisinya serta menggunakan SUMIF atau SUMIFS untuk menjumlahkan kolom yang terdapat dalam tabel Penerimaan Barang.

Rumus yang selanjutnya adalah untuk kolom Mutasi Out atau kolom G dan hampir sama dengan kolom F rumus inipun tetap menggunakan gabungan dari rumus Excel IF, AND, SUMIF dan SUMIFS.

Adapun rumus Excel tersebut adalah sebagai berikut :

=IF(AND($D$5="Semua";$D$7="Semua");SUMIF(Out!$H$6:$H$21;'Stok Barang'!C13;Out!$J$6:$J$21);IF(AND($D$5="Pilih Gudang";$D$7="Semua");SUMIFS(Out!$J$6:$J$21;Out!$H$6:$H$21;'Stok Barang'!C13;Out!$D$6:$D$21;'Stok Barang'!$D$6);IF(AND($D$5="Semua";$D$7="Periode");SUMIF(Out!$H$6:$H$21;'Stok Barang'!C13;Out!$J$6:$J$21)-SUMIFS(Out!$J$6:$J$21;Out!$H$6:$H$21;'Stok Barang'!C13;Out!$C$6:$C$21;"<"&'Stok Barang'!$D$8)-SUMIFS(Out!$J$6:$J$21;Out!$H$6:$H$21;'Stok Barang'!C13;Out!$C$6:$C$21;">"&'Stok Barang'!$D$9);IF(AND($D$5="Pilih Gudang";$D$7="Periode");SUMIFS(Out!$J$6:$J$21;Out!$H$6:$H$21;'Stok Barang'!C13;Out!$D$6:$D$21;'Stok Barang'!$D$6)-SUMIFS(Out!$J$6:$J$21;Out!$H$6:$H$21;'Stok Barang'!C13;Out!$D$6:$D$21;'Stok Barang'!$D$6;Out!$C$6:$C$21;"<"&'Stok Barang'!$D$8)-SUMIFS(Out!$J$6:$J$21;Out!$H$6:$H$21;'Stok Barang'!C13;Out!$D$6:$D$21;'Stok Barang'!$D$6;Out!$C$6:$C$21;">"&'Stok Barang'!$D$9);""))))

Sumber data dari mutasi Out ini adalah tabel Pengeluaran Barang yang telah kita buat sebelumnya dengan tampilan data sesuai filter yang kita lakukan.

Khusus untuk cara menggabungkan rumus Excel IF dengan rumus Excel AND telah saya jelaskan dalam artikel sebelumnya dan silahkan untuk dipelajari.

Rumus untuk mengisi kolom H atau kolom Jumlah Stok Akhir adalah sebagai berikut :

=E13+F13-G13

Rumus tersebut diatas tentu saja akan mudah untuk dipahami karena hanya menjumlahkan kolom E, F dan G saja.

Rumus yang terakhir adalah Satuan dalam kolom Stok akhir dan rumus tersebut adalah sebagai berikut :

=IF(H13>0;VLOOKUP(C13;Barang!$B$6:$D$16;3;0);"")

Rumus tersebut pada dasarnya hanya akan memunculkan satuan barang sesuai dengan kode yang terdapat dalam kolom C.

Jika Anda bertanya kenapa digabungkan dengan rumus Excel IF jawabannya adalah karena Satuan tersebut akan muncul jika terdapat atau muncul angka dalam kolom H.

7. Membuat Tabel Sampling Stok

Pada dasarnya tabel ini hanya tambahan saja dan tidak ada pengaruhnya terhadap penghitungan stok barang.

Sampling stok biasanya dilakukan untuk melakukan cek fisik barang tertentu sesuai dengan pilihan kita secara random.

Dalam bagian ini disertakan juga filter data sehingga kita bisa melakukan cek fisik barang sesuai dengan lokasi gudang.

Itulah pembahasan kita kali ini tentang cara menghitung stok barang untuk beberapa gudang yang berbeda dalam Excel.

Penjelasannya cukup panjang dan silahkan dipelajari tahap demi tahapnya supaya tidak terjadi error pada excelnya.

Jika ingin melihat contoh filenya silahkan request melalui Fans Page Facebook yang saya cantumkan dalam halaman kontak atau ikuti link berikut ini :

Nama File : Contoh Stok 2 Gudang
Ukuran File : 26 kb
Link : Contoh File

Sebenarnya saya lebih ingin pembaca untuk mempelajari langkah - langkahnya seperti yang saya uraikan diatas supaya bisa mengubah atau mengedit contoh filenya dan disesuaikan dengan kebutuhan.

Jika ada pola atau rumus yang dirasa tidak sesuai dengan yang diuraikan oleh saya mari kita diskusikan melalui kolom komentar dibawah artikel ini.

Terkhir semoga pembahasan Stok Barang dalam artikel ini bermanfaat untuk semua pembaca.