Cara Membuat Neraca Saldo Dalam Excel - Bagian II

Membuat Neraca Saldo Dalam Excel - Artikel ini merupakan lanjutan dari artikel sebelumnya.

Dalam artikel sebelumnya kita sudah menyelesaikan Sheet CoA dan Sheet Jurnal.

Kedua Sheet tersebut akan digunakan dalam Sheet yang ketiga yaitu Buku Besar.

Untuk itu bagi pembaca yang belum mempelajari pembahasan yang pertama silahkan buka dan pelajari terlebih dahulu.

Karena banyak bagian yang terhubung antara Sheet CoA dan Sheet Jurnal dengan Buku Besar ini.

Membuat Buku Besar Untuk Neraca Saldo Dalam Excel

Selanjutnya Sheet yang ketiga atau Sheet Buku Besar angka saldo setiap akunnya akan digunakan dalam Neraca Saldo.

Adapun tampilan dari Sheet yang ketiga atau Sheet Buku Besar tersebut adalah sebagai berikut :

Dalam contoh filenya saya sudah buat Buku Besar tersebut untuk masing - masing CoA-nya.

Untuk rumus - rumusnya mari kita bahas kolom perkolomnya satu persatu sampai dengan selesai.

1. Rumus Kode, Nama dan Posisi

Ketiga Cell ini akan menampilkan data yang sumbernya dari Sheet CoA.

Adapun masing - masing rumusnya adalah sebagai berikut :

• Kode : tidak ada rumus tetapi sudah dibuatkan Dropdown list untuk memilih CoA
• Nama : =IF(B3<>"";VLOOKUP(B3;Tabel_CoA;2;0)) 
• Posisi : =IF(B3<>"";VLOOKUP(B3;Tabel_CoA;3;0))

Untuk informasi bahwa bagian Cell Kode wajib untuk dibuatkan karena digunakan didalam Tabel Buku Besar.

2. Rumus Saldo Awal, D/K dan Jmlh Baris

Sebenarnya ketiga cell ini hampir sama dengan tiga cell sebelumnya yaitu akan menampilkan angka atau data dari Sheet CoA.

Adapun rumus - rumusnya adalah sebagai berikut :

• Saldo Awal : =IF(B3<>"";VLOOKUP(B3;Tabel_CoA;5;0))
• D/K : =IF(B3<>"";VLOOKUP(B3;Tabel_CoA;4;0))
• Jmlh Baris : =COUNTIF(Jurnal;B3)

Untuk Cell Saldo Awal dan Jmlh Baris sifatnya wajib untuk dibuat karena akan diguakan dalam Tabel Buku Besar.

Khusus untuk Jmlh Baris konsepnya adalah akan menghitung jumlah transaksi CoA yang bersangkutan didalam Sheet Jurnal.

Jika angka didalam Cell ini tidak sama dengan jumlah baris transaksi dalam Buku Besar maka kita tinggal Insert baris untuk menampilkan seluruh transaksinya.

3. Rumus Kolom Kode

Kolom kode akan menampilkan nomor urut transaksi sesuai dengan kode Akunnya masing - masing.

Baca Juga : Cara Membuat Buku Besar Otomatis di Excel - bagian II

Konsep Kode ini sudah saya jelaskan secara detail didalam artikel tentang Buku Besar dan silahkan untuk dipelajari.

Rumus didalam Kolom Kode ini saya bagi menjadi dua bagian.

Bagian pertama adalah rumus untuk kolom Kode paling atas atau dalam contoh diatas adalah Cell A8 dan rumusnya adalah sebagai berikut :

=B3&"-"&1

Selanjutnya rumus yang kedua adalah untuk kolom Kode baris kedua dan seterusnya, rumusnya adalah sebagai berikut :

=IFERROR(IF((MID(A8;7;LEN(A8)-6)+1)<=COUNTIF(Jurnal;LEFT(A8;5));LEFT(A8;5)&"-"&MID(A8;7;LEN(A8)-6)+1;"");"")

Untuk cell selanjutnya silahkan copy dan pastekan rumus yang kedua diatas.

Posisi kode ini jumlahnya tidak akan melebihi angka dalam Cell G5.

Misalnya dalam CoA Kas dengan akun 1.1.1 jumlah barisnya adalah 12.

Maka dalam kolom kode Akun yang muncul dimulai dari 1.1.1-1 sampai dengan 1.1.1-12.

4. Rumus Tanggal, No. Jurnal dan Uraian

Ketiga kolom ini akan menampilkan rincian transaksi dari Sheet Jurnal sesuai dengan kode yang muncul dalam kolom Kode.

Adapun rumus - rumusnya adalah sebagai berikut :

• Kolom Tanggal : =IFERROR(INDEX(Tgl;MATCH('Buku Besar'!A8;Ref;0));"")
• No. Jurnal : =IFERROR(INDEX(No_Jurnal;MATCH('Buku Besar'!A8;Ref;0));"")
• Uraian : =IFERROR(INDEX(Ket;MATCH('Buku Besar'!A8;Ref;0));"")

Silahkan perhatikan rumus diatas, saya menggunakan Define Name atau Nama Range yang sudah dibahas dalam artikel sebelumnya.

Supaya tidak bingung silahkan buka dan pelajari artikel bagian pertama tersebut.

5. Rumus Kolom Debet dan Kredit

Kedua kolom ini prinsipnya sama dengan tiga kolom sebelumnya yaitu akan menampilkan transaksi sesuai dengan Kodenya.

Adapun rumus untuk kedua kolom ini adalah sebagai berikut :

• Debet : =IFERROR(INDEX(Debet;MATCH('Buku Besar'!A8;Ref;0));0)
• Kredit : =IFERROR(INDEX(Kredit;MATCH('Buku Besar'!A8;Ref;0));0)

Jika belum memahami cara penggunaan dari masing - masing fungsi dasarnya silahkan buka dan pelajari dalam kategorinya masing - masing.

6. Rumus Kolom Saldo

Kolom Saldo ini merupakan kolom yang sangat penting.

Karena angka saldo inilah yang akan digunakan didalam Laporan Keuangan.

Kesalahan penghitungan saldo akan mengakibatkan kesalahan pada laporan keuangan.

Rumus dalam kolom Saldo ini juga dibagi menjadi dua bagian.

Rumus pertama untuk baris saldo paling atas dan rumusnya adalah sebagai berikut :

=IF(VLOOKUP(LEFT(A8;5);Tabel_CoA;4;0)="D";G3+E8-F8;G3+F8-E8)

Rumus yang kedua untuk baris kolom saldo yang kedua dan seterusnya, rumusnya adalah sebagai berikut :

=IFERROR(IF(VLOOKUP(LEFT(A9;5);Tabel_CoA;4;0)="D";G8+E9-F9;G8+F9-E9);0)

Rumus ini dibagi dua karena baris pertama menyertakan saldo awal sedangkan baris yang kedua dan selanjutnya tidak menyertakannya.

Silahkan ikuti langkah - langkah diatas dari awal sampai akhir dan jangan sampai ada yang terlewat.

Untuk contoh filenya saya akan sertakan dalam pembahasan artikel bagian yang ketiga.

Jika akan membaca artikel bagian kedua dan ketiga silahkan klik link dibawah ini.

Artikel Bagian I | Artikel Bagian III 

Share :